大智慧修改的轨道疯更加明确阻力.支撑更实用主图公式
大智慧修改的轨道疯更加明确阻力.支撑更实用主图公式
把疯傻轨道拿来但是必须加配合才能凸显这个轨道的功能.我们编制轨道线的目的和黄金分割是一样的就是有利于找到阻力位和支撑点只有知道了阻力支撑才明白那里可以买.那里必须卖.因此仅仅靠轨道线来确定买卖似乎不妥.必须左以旁证才能加强他的可信度.现在我就一一说明：---------------
【1.120天牛熊线】这是120天的均线.把它用红绿线标示红色表示炒股是走牛势.反之绿色为熊市我们用它判断该股的强弱.
【2.K线】不必说明
【3.疯傻轨道】是以【CC:=ABS((2*CLOSE+HIGH+LOW)/4-MA(CLOSE,18))/MA(CLOSE,18);】为基调编制的.其实就是股价的重心和18天均线距离来确定的轨道线.基本线就是当中那一条【DD:=DMA(CLOSE,CC)】.你明白这个轨道的构成.你就清楚的知道当股价涨跌离开18天均线越远就会越出现需要买卖的可能性.因为任何股票不会老涨下去.同样也不会老是跌个没完.简单的说就是涨的多要卖.跌的多就可以考虑买.很明显轨道的语言不完美.那是因为仅仅以18天本身就有片面性.每个股票具有自身的特点.受制于消息面.基本面.等等的因素.18天均线绝不是唯一的依靠.
【4.J合力】无奈我们加进了KDJ的影响力.而KDJ也有个取多少天的问题.我们不得不用综合法取9---54天的合成形成的数据来确定是不是顶或者底.尽可能的接近实际.
【5.压力支撑】近期的两个高点以及两个低点连线【图上是虚线】形成一个通道.股价的上突破或者下突破都可能是阻力位或者支撑位.它的力度和可靠性远远大于轨道线.而且来得及时.一旦突破就会产生反转形态.其指导作用不可小视.不过他的参数N必须及时矫正到当时的走势状态就是能够足以反应【就近两个高低点】的连线.
【6.波浪顶底----未来函数部分可删除】这个部分可删可留.原因里边有未来函数.做为参考顶底的历史功能还是可以用.炒股也离不开【以史为鉴】的道理.所以我不认为必须删除.未来函数不可怕.【可怕的是你偏要跟着未来走】.
他的参数K也要调整到合乎你的股票历史状态.因为每个股的发展历史不同.K的数据也就得跟上历史的趋势才行.你一定能调整到和K线相符合.
【7.主散带】主力的成本带是土色.散户的成本带是天兰色.你一看就知道庄家的成本一向小于散户.这说明两件事.
【A】如果股价低于庄家成本.肯定会回归起来.只是时间问题.其原因是多方面的.而且大部份是外部原因.比如大盘在下跌中---或者前期已涨过头庄家已是钱囊鼓鼓.下来的目的是要再捞一把.
【B】股价高于散户成本时.连散户都赚钱了.不要多久一定跌下来.因为庄家不会放眼不管.也叫你也【沟满壕平】从庄家手里把钱掏走.你必须清醒的知道在股市这个【锅里钱是有限的】而向股市要钱的可不少.国家要税.券商要钱.股票东家要钱.操盘的庄家要钱.到你手里还有多少可想而知.所以咱们常说【获利了解】就是告诫你别贪.
好啦一个个我们都分析过了.可现在的问题就是怎么综合的看这个公式.就是要把我们的思路整合到一起看问题.我们软件里公式一点都不少.就是难在能整体看公式那叫【综合利用】高抛低吸小孩都知道.可是能做到【高抛低吸】的人在股市为数不多.因为哪是高.哪是低.看历史一清二楚.看未来完全是瞎猜.那么公式就没有用了吗.还是要用的.你模糊看不清的原因就是你自己.不相信你自己.涨了还想涨.跌了就觉得差不多了.【看多的总看涨】.【看空的老等着再跌】.什么机会都错过去了.
不.不.别唠叨起来没完.告诉你这个公式有【六道金牌】.你一个不信.两个不信.三个.四个.你还不信.硬要坐【过山车】该下车不下.能上车你却不上.没赚着钱.还老吃【后悔药】神仙也无可奈何.
这个主图里买卖点清清楚楚.
第一：重要的是已经赚钱.图上发生卖出信号【长上影线.十字星.散户线上.疯傻轨道的上线.kdj>100.放量不滞涨.等等】.就赶快下车.后边涨上天。也不后悔.因为你是赚钱出来的而且已看到卖出信号.
第二：股价在庄家成本以下.三天不出现新低.不破支撑线.MA5.KDJ,调头.跌破疯傻轨道的下线.又会来.就是买入信号.你不妨以【主动买套】的策略.试探买的.逐步加仓.
第三：我们不赌，但是也不靠闯大运.而是利用智慧和悟性买卖要多次分批进行.除非你有十足的把握.或者有不怕搞错的心理准备.
我的目的就是想通过这个主图和你交流如何利用公式的方法.我们不能只是为发而发公式.或者说是为了显摆自己.我建议你在下载公式的同时不要忘了下载我这个说明.慢慢的【细嚼慢咽】品品滋味.对于你炒股会大有收获.比只看公式还有用的.我可亲的粉丝们.
{j轨道疯}
INPUT:K(10,2,50),N(5,1,50);
{1.120天牛熊线}
牛熊:MA(C,120),COLORgray;
PARTLINE(牛熊 ,(牛熊>REF(牛熊,1))-1,rgb(0,255,0),1,rgb(255,0,0) ),LINETHICK2,LAYER0;
{2.K线}
STICKLINE(CLOSE>OPEN or CLOSE=OPEN and CLOSE>REF(CLOSE,1),LOW,HIGH,0.1,0),colorred;
STICKLINE(CLOSE>OPEN or CLOSE=OPEN and CLOSE>REF(CLOSE,1),OPEN,CLOSE,0,0),colorred;
STICKLINE(CLOSE<OPEN or CLOSE=OPEN and CLOSE<=REF(CLOSE,1),LOW,HIGH,0.1,0),colorcyan;
STICKLINE(CLOSE<OPEN or CLOSE=OPEN and CLOSE<=REF(CLOSE,1),OPEN,CLOSE,0,0),colorcyan;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,8,0 ),COLOR006600;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,7,0 ),COLOR008800;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,6,0 ),COLOR00AA00;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,5,0 ),COLOR00BB00;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,4,0 ),COLOR00CC00;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,3,0 ),COLOR00DD00;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,2,0 ),COLOR00EE00;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,1,0 ),COLOR00FF00;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,0,0 ),COLOR00FF00;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,8,0) ,COLOR000066;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,7,0) ,COLOR000088;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,6,0) ,COLOR0000AA;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,5,0) ,COLOR0000BB;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,4,0) ,COLOR0000CC;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,3,0) ,COLOR0000DD;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,2,0) ,COLOR0000EE;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,1,0) ,COLOR0000FF;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,0,0) ,COLOR0000FF;
{3.疯傻轨道}
CC:=ABS((2*CLOSE+HIGH+LOW)/4-MA(CLOSE,18))/MA(CLOSE,18);
DD:=DMA(CLOSE,CC);
上:(1+7/100)*DD;
疯:(1+14/100)*DD;
下:(1-7/100)*DD;
中:(上+下)/2;
傻:(1-14/100)*DD;
DRAWTEXT(DISPSTATUS=2 AND 疯,疯,NUMTOSTRN(疯,2)),ColorEA91B5;
PARTLINE(疯 ,(疯>REF(疯,1))-1,rgb(0,255,10),1,rgb(255,0,255) ),LINETHICK1,LAYER0;
DRAWTEXT(DISPSTATUS=2 AND 上,上,NUMTOSTRN(上,2)),ColorEA91B5;
PARTLINE(上 ,(上>REF(上,1))-1,rgb(0,255,10),1,rgb(255,0,255) ),LINETHICK1,LAYER0;
DRAWTEXT(DISPSTATUS=2 AND 中,中,NUMTOSTRN(中,2)),ColorEA91B5;
PARTLINE(中 ,(中>REF(中,1))-1,rgb(0,255,10),1,rgb(255,0,255) ),LINETHICK2,LAYER0;
DRAWTEXT(DISPSTATUS=2 AND 下,下,NUMTOSTRN(下,2)),ColorEA91B5;
PARTLINE(下 ,(下>REF(下,1))-1,rgb(0,255,10),1,rgb(255,0,255) ),LINETHICK1,LAYER0;
DRAWTEXT(DISPSTATUS=2 AND 傻,傻,NUMTOSTRN(傻,2)),ColorEA91B5;
PARTLINE(傻 ,(傻>REF(傻,1))-1,rgb(0,255,10),1,rgb(255,0,255) ),LINETHICK1,LAYER0;
{4.J合力}
J9:EMA("KDJ.J"(9,3,3),5) ,COLOR0000FF,LINETHICK0;
J18:EMA("KDJ.J"(18,3,3),5) ,COLOR00FFFF,DOTLINE,LINETHICK0;
J27:EMA("KDJ.J"(27,3,3),5) ,COLOR00FF00,DOTLINE,LINETHICK0;
J36:EMA("KDJ.J"(36,3,3),5) ,COLOR0077FF,DOTLINE,LINETHICK0;
J45:EMA("KDJ.J"(45,3,3),5) ,COLORFF9900,LINETHICK0;
J54:EMA("KDJ.J"(54,3,3),5) ,COLORFF9900,LINETHICK0;
J合力:(3*J9+2*J18+J27+J36+J45+J54)/9,COLOR00FFCC,LINETHICK0;
合力顶:=J合力>85 ;
合力低:=J合力<15;
DRAWTEXT(CROSS(0,合力顶) ,H*1.04,'【顶】'),ALIGN1,COLOR00FFFF,LINETHICK3,LAYER3;
DRAWTEXT(CROSS(0,合力低) ,L*0.97,'【低】'),ALIGN1,COLOR0077FF,LINETHICK3,LAYER0;
{低部}
DIBU:= "KDJ.K"(9,3,3)<15 AND "KDJ.D"(9,3,3)<15 AND "KDJ.K"(18,3,3)<15 AND "KDJ.D"(18,3,3)<15
AND "KDJ.K"(27,3,3)<20 AND "KDJ.D"(27,3,3)<20 AND "KDJ.D"(36,3,3)<20 AND "KDJ.D"(54,3,3)<20;
DRAWTEXT(CROSS(0,DIBU) ,L*0.95,'【买】'),ALIGN1,COLOR00ffff,LINETHICK2,LAYER3;
DRAWTEXT(CLOSE>=1.094*REF(CLOSE,1),CLOSE*1.04,'停'),ALIGN1,COLORCYAN;
{VARZT:=BARSLAST(C/REF(C,1)>1.094);}
{以下是未来函数部分----可删除}
{5.压力支撑}
drawtextabs(5,5,'【高低转向幅度:K='+K+'%.K可以根据股性调整】'),Color05FFFF,linethick4;
AG1:=ref(h,N)=hhv(h,2*N+1);
B1:=filter(AG1,N);
C1:=backset(B1,N+1);
D1:=filter(C1,n);{高点}
AG2:=ref(l,N)=llv(l,2*N+1);
B2:=filter(AG2,N);
C2:=backset(B2,N+1);
D2:=filter(C2,N);{低点}
E1:=(ref(llv(l,2*N),1)+ref(hhv(h,2*N),1))/2; E2:=(h+l)/2;{高低点出现在同一K线上时可作取舍}
H1:=(D1 AND not(D2 AND E1>=E2)) OR barstatus=2 OR barscount(c)=1;
L1:=(D2 AND not(D1 AND E1<E2)); H2:=D1 AND not(D2 AND E1>=E2);
X1:=ref(barslast(H1),1)+1; F1:=backset(H1 AND count(L1,X1)>0,llvbars
(if(L1,l,10000),X1));
G1:=F1>ref(F1,1); I1:=backset(G1,2); LD:=I1>ref(I1,1);{过滤后低点}
L2:=LD OR barstatus=2 OR barscount(c)=1;
X2:=ref(barslast(L2),1)+1; F2:=backset(L2 AND count(H2,X2)>0,hhvbars
(if(H2,h,0),X2));
G2:=F2>ref(F2,1); I2:=backset(G2,2); HD:=I2>ref(I2,1);{过滤后高点}
R1:=backset(barstatus=2,barslast(HD)+1);
S1:=R1>ref(R1,1); {前一高}
T1:=backset(barstatus=2,barslast(LD)+1);
U1:=T1>ref(T1,1); {前一低}
R2:=backset(S1,ref(barslast(HD),1)+2);
S2:=R2>ref(R2,1); {前二高}
T2:=backset(U1,ref(barslast(LD),1)+2);
U2:=T2>ref(T2,1); {前二低}
短期压力:drawline(S2,h,S1,h,1),DOTLINE,Colorred;
短期支撑:drawline(U2,l,U1,l,1),DOTLINE,Colorgreen;
{6.升降转向.波浪顶底}
High1:=PEAK(1,k,1);
Low1:=TROUGH(2,k ,1);
降:DRAWLINE(H=High1,HIGH,L=Low1,LOW,0),COLOR00FF00,LINETHICK2;
升:DRAWLINE(L=Low1,LOW,H=High1,HIGH,0),COLORRED,LINETHICK2;
HHD:=FILTER(BACKSET(FILTER(ref(H,10)=HHV(H,2*10+1),10),10+1),10);
LLD:=FILTER(BACKSET(FILTER(ref(L,10)=LLV(L,2*10+1),10),10+1),10);
A:=ref(H,BARSLAST(HHD));
B:=ref(L,BARSLAST(LLD));
TT1:=BARSLAST(HHD)<BARSLAST(LLD) AND NOT(HHD) ;
TT2:=BARSLAST(HHD)>BARSLAST(LLD) AND NOT(LLD);
波浪顶:if(TT1,A,A),COLORFF00FF,POINTDOT,LINETHICK2;
波浪底:if(TT2,B,B),COLOR80FF00,POINTDOT,LINETHICK2;
{7.主散带}
aa:=cost(95);
散户带上沿:(20*aa+19*ref(aa,1)+18*ref(aa,2)+17*ref(aa,3)+16*ref(aa,4)+15*ref(aa,5)+14*ref(aa,6)
+13*ref(aa,7)+12*ref(aa,8)+11*ref(aa,9)+10*ref(aa,10)+9*ref(aa,11)+8*ref(aa,12)
+7*ref(aa,13)+6*ref(aa,14)+5*ref(aa,15)+4*ref(aa,16)+3*ref(aa,17)+2*ref(aa,18)+
ref(aa,20))/210,COLORff9900;
a2:=cost(75);
散户带下沿:=(20*a2+19*ref(a2,1)+18*ref(a2,2)+17*ref(a2,3)+16*ref(a2,4)+15*ref(a2,5)+14*ref(a2,6)
+13*ref(a2,7)+12*ref(a2,8)+11*ref(a2,9)+10*ref(a2,10)+9*ref(a2,11)+8*ref(a2,12)
+7*ref(a2,13)+6*ref(a2,14)+5*ref(a2,15)+4*ref(a2,16)+3*ref(a2,17)+2*ref(a2,18)+
ref(a2,20))/210;
a3:=cost(55);
主力带上沿:=(20*a3+19*ref(a3,1)+18*ref(a3,2)+17*ref(a3,3)+16*ref(a3,4)+15*ref(a3,5)+14*ref(a3,6)
+13*ref(a3,7)+12*ref(a3,8)+11*ref(a3,9)+10*ref(a3,10)+9*ref(a3,11)+8*ref(a3,12)
+7*ref(a3,13)+6*ref(a3,14)+5*ref(a3,15)+4*ref(a3,16)+3*ref(a3,17)+2*ref(a3,18)+
ref(a3,20))/210;
a4:=cost(35);
主力带下沿:=(20*a4+19*ref(a4,1)+18*ref(a4,2)+17*ref(a4,3)+16*ref(a4,4)+15*ref(a4,5)+14*ref(a4,6)
+13*ref(a4,7)+12*ref(a4,8)+11*ref(a4,9)+10*ref(a4,10)+9*ref(a4,11)+8*ref(a4,12)
+7*ref(a4,13)+6*ref(a4,14)+5*ref(a4,15)+4*ref(a4,16)+3*ref(a4,17)+2*ref(a4,18)+
ref(a4,20))/210;
FILLRGN(散户带上沿,散户带下沿,散户带上沿>散户带下沿,RGB(0,0,255)),LAYER5;
FILLRGN(主力带上沿,主力带下沿,主力带上沿>主力带下沿,RGB(100,0,60)),LAYER5;
FILLRGN(主力带上沿,散户带下沿,主力带上沿<散户带下沿,RGB(80,80,80)),LAYER5;
