通达信峰谷撑压源码主图+选股贴图）
1、峰谷撑压（源码）
{峰谷撑压 主图 TDX}
{用途: 画趋势辅助用 结合王子教材中画线部分和量柱量群分析 通过图中所示以趨勢線等理論再进行手动画线分析效果更佳}
{未来 BACKSET 用法:BACKSET(X,N),若X非0,则将当前位置到N周期前的数值设为1.}
{例如:BACKSET(CLOSE>OPEN,2)若收阳则将该周期及前一周期数值设为1,否则为0 }
{参数N、N1、N2、N3 均为 1, 300, 5; 可任意调周期,以各期不同点位}
{峰线}
AA:=REF(H,N)=HHV(H,2*N+1);{N日前的最高价}
QY:=BACKSET(AA,N+1);{周期记录}
CC:=FILTER(QY,N) AND H=HHV(H,N+1);{周期过滤 最高价最高值}
DDD:=BARSLAST(CC),NODRAW;{CC条件成立的天数}
GDTS:=IF(CC,CURRBARSCOUNT,0),NODRAW;{CC成立 返回交易日的周}
DINGBUTS:=IF(DDD,REF(GDTS,DDD),GDTS),NODRAW;{DDD成立,返回DDD日前的GDTS,否则返回GDTS}
GDCS1:=CONST(DINGBUTS),NODRAW;{取DINGBUTS值}
GDCS13:=CONST(REF(HIGH,GDCS1-1));
DINGBUTS1:=REF(DINGBUTS,DDD+1),NODRAW;
GDCS2:=CONST(DINGBUTS1);
GDCS23:=CONST(REF(HIGH,DINGBUTS1-1));
XG1:=BACKSET(ISLASTBAR,GDCS1);{ ISLASTBAR 判断是否为最后一个周期}
XG2:=BACKSET(ISLASTBAR,DINGBUTS1);
STICKLINE(XG2,GDCS23,GDCS23,0.5,1),COLORWHITE,LINETHICK3;{白线}
STICKLINE(XG1,GDCS13,GDCS13,0.5,1),COLORYELLOW,LINETHICK3;{黄线}
{谷线}
AA1:=REF(L,N1)=LLV(L,2*N1+1);
QY1:=BACKSET(AA1,N1+1);
CC1:=FILTER(QY1,N1) AND L=LLV(L,N1+1);
DD1:=BARSLAST(CC1);
DDTS:=IF(CC1,CURRBARSCOUNT,0);
DDTS1:=IF(DD1,REF(DDTS,DD1),DDTS);
DDCS1:=CONST(DDTS1);
DDCS13:=CONST(REF(L,DDCS1-1));
DDTS2:=REF(DDTS1,DD1+1);
DDCS2:=CONST(DDTS2);
DDCS23:=CONST(REF(L,DDTS2-1));
XD1:=BACKSET(ISLASTBAR,DDCS1);
XD2:=BACKSET(ISLASTBAR,DDTS2);
STICKLINE(XD2,DDCS23,DDCS23,0.5,1),COLORMAGENTA,LINETHICK3; {洋红线}
STICKLINE(XD1,DDCS13,DDCS13,0.5,1),COLORCYAN,LINETHICK3; {海蓝线}
{压力支撑}
M:=INTPART(3*N2/5);{压力线取}
AAA:=REF(H,M)=HHV(H,2*M+1);
QYY:=BACKSET(AAA,M+1);
CCC:=FILTER(QYY,M) AND H=HHV(H,M+1);
DDDD:=BARSLAST(CCC),NODRAW;
GDTSS:=IF(CCC,CURRBARSCOUNT,0),NODRAW;
DINGBUTSS:=IF(DDDD,REF(GDTSS,DDDD),GDTSS),NODRAW;
GDCS11:=CONST(DINGBUTSS),NODRAW;
DINGBUTS11:REF(DINGBUTSS,DDDD+1),NODRAW;
GDCS22:=CONST(DINGBUTS11);
高点压力M:DRAWLINE(CURRBARSCOUNT=GDCS22,H,CURRBARSCOUNT=GDCS11,H,1),COLORGREEN;
W:=INTPART(3*N3/5);
AA11:=REF(L,W)=LLV(L,2*W+1);
QY11:=BACKSET(AA11,W+1);
CC11:=FILTER(QY11,W) AND L=LLV(L,W+1);
DD11:=BARSLAST(CC11);
DDTSS:=IF(CC11,CURRBARSCOUNT,0);
DDTS11:=IF(DD11,REF(DDTSS,DD11),DDTSS);
DDCS11:=CONST(DDTS11);
DDTS22:=REF(DDTS11,DD11+1);
DDCS22:=CONST(DDTS22);
低点支撑M:DRAWLINE(CURRBARSCOUNT=DDCS22,L,CURRBARSCOUNT=DDCS11,L,1),COLORRED;
{ZGSTAR:=(高点压力M+低点支撑M)/2;
ZGEND:=CONST((高点压力M+低点支撑M)/2);
STARDAY:=IF(DDCS2<GDCS2,DDCS2,GDCS2);
中轨:DRAWLINE(CURRBARSCOUNT=STARDAY,ZGSTAR,ISLASTBAR,ZGEND,1),COLORFF55BB,LINETHICK2;}
{DRAWKLINE(H,O,L,C);}
{主图中的倍量K线如何变黄色}
V2V:=V/REF(V,1)>=1.9 AND C>REF(C,1);
STICKLINE(V2V,O,C,-1,0),COLORYELLOW;
{涨停}
ZT:=C/REF(C,1)>1.097;
STICKLINE(ZT,O,C,-1,0),COLORMAGENTA;
{以下复制到参数精灵 注: PARAM第一字母大写后面小写
请设置计算参数:
峰顶线==== N: PARAM#0 (1--300)==黄白色
谷底线====N1: PARAM#1 (1--300)==洋红蓝
高点压力==N2: PARAM#2 (1--300)==绿线
低点支撑==N3: PARAM#3 (1--300)==红线};
2、峰谷撑压（选股）
{突破峰线（黄白线）选股}
N:=5; N1:=5; N2:=5; N3:=5;
AA:=REF(H,N)=HHV(H,2*N+1);{N日前的最高价}
QY:=BACKSET(AA,N+1);{周期记录}
CC:=FILTER(QY,N) AND H=HHV(H,N+1);{周期过滤 最高价最高值}
DDD:=BARSLAST(CC),NODRAW;{CC条件成立的天数}
GDTS:=IF(CC,CURRBARSCOUNT,0),NODRAW;{CC成立 返回交易日的周}
DINGBUTS:=IF(DDD,REF(GDTS,DDD),GDTS),NODRAW;{DDD成立,返回DDD日前的GDTS,否则返回GDTS}
GDCS1:=CONST(DINGBUTS),NODRAW;{取DINGBUTS值}
GDCS13:=CONST(REF(HIGH,GDCS1-1));
DINGBUTS1:=REF(DINGBUTS,DDD+1),NODRAW;
GDCS2:=CONST(DINGBUTS1);
GDCS23:=CONST(REF(HIGH,DINGBUTS1-1));
XG1:=BACKSET(ISLASTBAR,GDCS1);{ ISLASTBAR 判断是否为最后一个周期}
XG2:=BACKSET(ISLASTBAR,DINGBUTS1);
TJ1:=IF(XG2,GDCS23,0);{白线}
TJ2:=IF(XG1,GDCS13,0);{黄线};
CROSS(C,TJ1);
CROSS(C,TJ2);
