公式网 股票指标公式源码分享 登录 注册
公式指标平网
未来函数检测
首页 金钻指标 通达信公式 大智慧公式 同花顺公式 文华财经公式 东财通公式 飞狐公式 操盘手公式 其他公式 公式解答 股票软件 股票池
当前位置:→ 公式网 > 通达信公式 > 正文 → 正文

龙抬头 只做可做的和该做的

发布时间:2017/2/17 7:20:01  浏览次数:

龙抬头 只做可做的和该做的

1.指标设计理念:A股跌跌不休,变幻无常,我等小散们要想在此险恶的环境生存实为不易。多年的实践证明,只有牢固树立正确投资理念、辅助以高胜率的技术指标,紧紧依靠严格的止赢、损纪律,方能在A股市场生存并有所收获。发现并只做基本面优质、盘小、股价跌透、初转入牛势的个股,可能不失为一种好办法,也是五里头近几年坚持的原则!
   2.本指标设计的依据:依据上述理念,利用最常用的KDJ指标1)跌透后转强;2)不同周期共振等原理,降低原KDJ指标的欺骗性,提高信号的可靠性。
   3.本公式取名J龙抬头,信号有3组:1)中线买:针对中线出现较大跌幅后转强反弹的个股;2)短优共振:指短周期J信号共振买点;3)长优共振:指长周期J信号共振买点。对于这样的3种信号,只是技术层面的可能买点,具体买卖请结合大盘、个股及个人的具体情况而定,风险自负!如果你用本公式赚钱了,是你用的操作有方,如果亏了,不要来骂我哦!
   4.市场是变幻无常的复杂世界,我们要做的是把复杂简单化.本次把指标以副图原码发出,由于做了基本面方面的限制,信号较少,许多个股不会出信号,请匆见怪,也不要迷信于公式!

源码

{均线进多头}
MA60:=MA(CLOSE,60);
MA120:=MA(CLOSE,120);
初2加3牛:=EXIST(CROSS(MA60,MA120),89) AND MA60>MA120 AND C>MA120 AND MA60>REF(MA60,1)
AND MA120>REF(MA120,1) AND C<LLV(C,120)*1.5;
{股价跌透}
股价跌透:=IF(C<HHV(C,610)*0.5,1,0) AND C<LLV(C,120)*1.5;
RSV1:=(CLOSE-LLV(LOW,21))/(HHV(HIGH,21)-LLV(LOW,21))*100,LINETHICK2;
K1:=SMA(RSV1,2,1);
D1:=SMA(K1,2,1);
J1:=3*K1-2*D1,COLOR0000FF,LINETHICK2;
RSV2:=(CLOSE-LLV(LOW,13))/(HHV(HIGH,13)-LLV(LOW,13))*100,LINETHICK2;
K2:=SMA(RSV2,2,1);
D2:=SMA(K2,2,1);
J2:=3*K1-2*D1,COLOR0000FF,LINETHICK2;
RSV4:=(CLOSE-LLV(LOW,55))/(HHV(HIGH,55)-LLV(LOW,55))*100,LINETHICK2;
K4:=SMA(RSV4,2,1);
D4:=SMA(K4,2,1);
J4:=3*K4-2*D4,COLOR0000FF,LINETHICK2;
RSV5:=(CLOSE-LLV(LOW,89))/(HHV(HIGH,89)-LLV(LOW,89))*100,LINETHICK2;
K5:=SMA(RSV5,2,1);
D5:=SMA(K5,2,1);
J5:=3*K5-2*D5,COLORFF00FF,LINETHICK2;
低短弹买:=LONGCROSS(J2,10,3) AND 股价跌透,COLORAAAAAA;
牛短线买:=LONGCROSS(J2,10,3) AND 初2加3牛,COLOR00FFFF;
中线买:LONGCROSS(J1,10,3) AND 股价跌透,COLORFF00FF;
A4:=LONGCROSS(J4,10,3);
A5:=LONGCROSS(J5,10,3);
GZBT1:=FILTER(COUNT(A4 OR A5,2)=2,2);
GZBT2:=A4 AND A5 AND 中线买;
短共振买:=低短弹买 AND  中线买;
长共振买:=GZBT1 OR GZBT2 AND 股价跌透;
{基本面部分}
LTP:=FINANCE(7)<300000000 AND FINANCE(1)<500000000;   {流通盘股小于3亿股,总盘小于5亿}
MGSY:=FINANCE(33)>0.02 AND BARSCOUNT(C)>30;
SYL:=C/FINANCE(33)<200 AND C/FINANCE(33)>5; {市盈率低于200}
JZC:=FINANCE(34)>2;{ 每股净资产}
{通达信去掉*、S、ST}
S2:=IF(NAMELIKE('S'),0,1);
S3:=IF(NAMELIKE('*'),0,1);
GJFW:=DYNAINFO(7)>3 AND DYNAINFO(7)<40;{3元-40元价格的股}
XGJ:=LTP AND MGSY AND SYL  AND JZC AND S2 AND S3  AND GJFW;
短优共振:短共振买 AND XGJ,COLOR0078FF,LINETHICK2;
长优共振:长共振买 AND XGJ,COLOR0000FF,LINETHICK2;

龙抬头 只做可做的和该做的 

资源下载链接   资源大小:unknow

手机移动版 - 关于我们 - 联系我们 - 广告合作 - 下载声明 - 网站帮助 - 友情链接 - 网站地图 - TOP
湘ICP备09016573号-3 增值电信业务经营ICP许可证:湘B2-20210269 湘公网安备43108102000039号
Copyright © GSZX.COM.CN ,All Rights Reserved.
股票公式,股票指标,股票软件,股票知识